Let M be a space of weight 2 cuspidal modular symbols with trivial character that corresponds to a Galois-conjugacy class of newforms, and let AM(C) be the cokernel of the period map. G. Shimura proved that AM(C) is the set of complex points of an abelian variety AM defined over Q. Let N be the level of M and let J0(N) be the Jacobian of the modular curve X0(N). Shimura constructed AM as a quotient of J0(N) by an abelian subvariety. More precisely, if I is the annihilator of M in the Hecke algebra, then AM = J0(N)/I J0(N).
When AM has dimension 1 it is an elliptic curve, and the theory of computing with AM is well developed, though many interesting problems remain. In the contrary case, when AM has dimension greater than 1, the theory of computation with AM is still in its infancy. Fortunately, it is possible to compute a number of interesting quantities about AM using algorithms that rely on our extensive knowledge of J0(N).
Magma contains functions for computing the modular degree, congruence modulus, upper and lower bounds on the order of the torsion subgroup, and the order of the component group of the closed fiber of the Néron model of AM at primes that exactly divide the level of M.
The modular degree of the space of modular symbols M, which is defined as follows. Let M be a space of modular symbols of weight 2 and trivial character. The modular degree of M is the square root of #ModularKernel(M). When M corresponds to an elliptic curve E=AM, then the modular degree of M is the degree of induced map X0(N) -> E.
Bound: RngIntElt Default: -1
The congruence number r of the space of modular symbols M. This is the index in Sk(Γ0(N), Z) of the sum L + W of the lattice W of cusp forms L corresponding to M and the lattice of cusp forms corresponding to the complement of L in S.
The following upper bound on the order of the torsion subgroup of the abelian variety A attached to the space of modular symbols M: (gcd) { #A(Fp) : 3 ≤p ≤(maxp), p not| N}, where N is the level of M. This bound is an isogeny invariant, so it is also a bound on the order of the torsion subgroup of the dual abelian variety Av of A.To compute a lower bound, use #SubgroupOfTorus(M,WindingElement(M)).
> E := ModularSymbols("54B");
> ModularDegree(E);
2
> CongruenceModulus(E);
6
We next verify directly that the congruence modulus is divisible by 3.
> A := ModularSymbols("27A"); A; // 27=54/2.
Modular symbols space of level 27, weight 2, and dimension 2
> A54 := ModularSymbols(A,54); A54; // all images of A at level 54.
Modular symbols space of level 54, weight 2, and dimension 4
> qE := qIntegralBasis(E,17);
> qA54 := qIntegralBasis(A54,17);
> &+qA54 - &+qE;
-3*q^4 + 3*q^5 - 3*q^8 + 3*q^10 - 3*q^11 + 9*q^13 + 3*q^16 + O(q^17)
> IntersectionGroup(E,A54); // however, the intersection is trivial.
Abelian Group of order 1
Ken Ribet proved that if E is an optimal elliptic curve quotient of J0(N), with N prime, and if fE is the corresponding newform, then the congruence modulus of fE equals the modular degree of E. The author is aware of no counterexamples to the following more general statement: "If E is an optimal elliptic curve of square-free conductor, then the congruence modulus of the newform fE attached to E equals the modular degree of E." An analogous statement for abelian varieties is false, even at prime level. The first counterexample is ModularSymbols("431F"), which corresponds to an abelian variety of dimension 24. In this case, the modular degree is 211.6947, whereas the congruence modulus is 210.6947.
The following code makes a table of congruence moduli and modular degrees for the elliptic curves of conductor near 54. Notice the counterexample at level 54.
> for N in [53..55] do > C := CuspidalSubspace(ModularSymbols(N,2)); > newforms := NewSubspace(C); > D := EllipticFactors(newforms,19); > for E in D do > printf "%o:\t%o,\t%o\n", N, ModularDegree(E), CongruenceModulus(E); > end for; > end for; 53: 2, 2 54: 2, 6 54: 6, 6 55: 2, 2
ModularKernel makes sense even for spaces of modular symbols of weight greater than 2. As in the case of weight 2, this number gives information about congruences between modular forms. The following example illustrates how ModularKernel suggest a congruence between a form of level 10 and weight 4 with a form of level 5.
> M := ModularSymbols(10,4);
> S := CuspidalSubspace(M);
> D := NewformDecomposition(S); D;
[
Modular symbols space of level 10, weight 4, and dimension 2,
Modular symbols space of level 10, weight 4, and dimension 4
]
> #ModularKernel(D[1]);
10
> f := qEigenform(D[1],8);
> g := qEigenform(D[2],8);
> g2 := Evaluate(g,Parent(g).1^2);
> f-(g+6*g2); // a congruence modulo 10!
-10*q^3 + 20*q^4 + 10*q^5 - 20*q^6 - 10*q^7 + O(q^8)
We provide several functions for computing the orders of component groups of optimal quotients of J0(N) at primes p that exactly divide N. Our algorithm involves Grothendieck's monodromy pairing on the character group of the toric part of the closed fiber at p of the Néron model of J0(N); the theory behind this algorithm is described in [Ste01] (or [Ste00]); see [KS00] for a computationally-oriented introduction to the algorithm. When N is prime, we use the Mestre and Oesterlé method to construct the character group of the torus, as described in [Mes86]. In general, the ideal theory of quaternion algebras is used.
Note: In the appendix to [Maz77], Mazur and Rapoport give an explicit formula for the order of the component group of J0(N) at primes p≥5 that exactly divide N. Their formula is not currently used by the ComponentGroupOrder function.
The RealTamagawaNumber function computes the order of the "component group at infinity".
The order of the component group at p. This is the order of the group of /line(F)p-points of the component group of the reduction modulo p of the Néron model of the abelian variety attached to the space of modular symbols M. At present, it is necessary that p exactly divides the level. If Sign(M) is not equal to 0, then only the odd part of the order is returned.
The order of the group of Fp-rational points of the component group of the space of modular symbols M. We require M to be associated to a single Galois-conjugacy class of newforms.
The number of connected components of AM(R).
The number of connected components of the subgroup AM(C) - of AM(C) on which complex conjugation acts as -1
We compute the orders of the component groups of some abelian varieties.
> X11 := ModularSymbols("11A"); // corresponds to X_0(11).
> ComponentGroupOrder(X11,11);
5
> TamagawaNumber(X11,11);
5
> RealTamagawaNumber(X11);
1
> MinusTamagawaNumber(X11);
1
> J37 := ModularSymbols("37"); J37;
Modular symbols space of level 37, weight 2, and dimension 4
> ComponentGroupOrder(J37,37);
3
> A, B := Explode(NewformDecomposition(J37));
> ComponentGroupOrder(A,37);
3
> ComponentGroupOrder(B,37);
1
We can also compute component groups of optimal quotients whose dimension is greater than 1. The abelian varieties B and C below correspond to the Jacobians labeled 65B and 65A in [FLS+01], respectively.
> J65 := ModularSymbols("65");
> A,B,C := Explode(SortDecomposition(NewformDecomposition(J65)));
> B;
Modular symbols space of level 65, weight 2, and dimension 4
> C;
Modular symbols space of level 65, weight 2, and dimension 4
> ComponentGroupOrder(B,5); // not the Tamagawa number
3
> ComponentGroupOrder(B,13);
3
> ComponentGroupOrder(C,5);
7
> ComponentGroupOrder(C,13);
1
> HeckeEigenvalueField(C);
Number Field with defining polynomial x^2 + 2*x - 1 over the
Rational Field
Mapping from: Univariate Quotient Polynomial Algebra in a over
Rational Field
with modulus a^2 + 2*a - 1 to Number Field with defining
polynomial x^2 + 2*x - 1 over the Rational Field given by a rule
[no inverse]
> ComponentGroupOrder(J65,5);
42
When the Atkin-Lehner involution Wp acts as +1 on a modular abelian variety A, the order of the component group can be larger than the Tamagawa number cp=[A(Qp):A0(Qp)] that appears in the conjecture of Birch and Swinnerton-Dyer.
> AtkinLehner(B,5); [1 0 0 0] [0 1 0 0] [0 0 1 0] [0 0 0 1] > ComponentGroupOrder(B,5); 3 > TamagawaNumber(B,5); 1
The real and minus Tamagawa numbers are defined for spaces of modular symbols of any weight over the rationals.
> Del := ModularSymbols("1k12A");
> Del;
Modular symbols space of level 1, weight 12, and dimension 2
Next we see that the period lattice associated
to Δ is rectangular.
> RealTamagawaNumber(Del);
2
> MinusTamagawaNumber(Del);
2
> Periods(Del,40);
[
(-0.0004853381649299516049241304429*i),
(0.001140737449583079336044545337)
]