Lie Algebras and Bilinear Forms

If J is the matrix of a bilinear form, the Lie algebra of derivations of J consists of the matrices X such that XJ + JXtr = 0.

Another way to construct a Lie algebra from an alternating form β with matrix J defined on a vector space V of dimension n over a field F is to set L = V direct-sum F and define the multiplication by [ei, ej] = β(ei, ej), where e1, e2, ..., en is a basis for V. (All other structure constants are 0.) This is the (generalised) Heisenberg algebra.

DerivationAlgebra(J) : AlgMatElt -> AlgLie
    Rep: MonStgElt                      Default: "Sparse"
    Check: BoolElt                      Default: false
The Lie algebra of derivations of the bilinear form with matrix J. The possible values for Rep are "Dense", "Sparse" and "Partial" with the default being "Sparse".

Example FldForms_lieC3 (H30E25)

Construct the Lie algebra preserving the standard alternating form of rank 6 over the field of 7 elements and check that it is a simple algebra of type C3. 
> J := StandardAlternatingForm(6,7);
> L := DerivationAlgebra(J);
> IsSimple(L);
true
> SemisimpleType(L);
C3

Example FldForms_lieG2 (H30E26)

Over a field of characteristic 2, the Lie algebra of an alternating form is no longer simple. In this example the Lie algebra L of the standard alternating form of rank 6 over GF(8) is of symplectic type C3 but has an ideal I of type G2. The dimension of the centre of L is 1 and so the ideal I will appear as either the first or second composition factor. 
> J := StandardAlternatingForm(6,8);
> L := DerivationAlgebra(J);
> SemisimpleType(L);
C3
> Dimension(Centre(L));
1
> CF := CompositionFactors(L);
> CF;
[
    Lie Algebra of dimension 1 with base ring GF(2^3),
    Lie Algebra of dimension 14 with base ring GF(2^3),
    Lie Algebra of dimension 1 with base ring GF(2^3),
    Lie Algebra of dimension 1 with base ring GF(2^3),
    Lie Algebra of dimension 1 with base ring GF(2^3),
    Lie Algebra of dimension 1 with base ring GF(2^3),
    Lie Algebra of dimension 1 with base ring GF(2^3),
    Lie Algebra of dimension 1 with base ring GF(2^3)
]
> exists(I){I : I in CF | Dimension(I) eq 14 };
true
> IsSimple(I);
true
> SemisimpleType(I);
G2
HeisenbergAlgebra(J) : AlgMatElt -> AlgLie
    Rep: MonStgElt                      Default: "Sparse"
    Check: BoolElt                      Default: false
The nilpotent Lie algebra whose structure constants are obtained from the alternating form with matrix J as described above. The possible values for Rep are "Dense", "Sparse" and "Partial" with the default being "Sparse".

Example FldForms_heisenberg (H30E27)

Continuing the previous example we construct an explicit isomorphism between the quotient of L by its G2 ideal and the Heisenberg algebra of the form. 
> Q := CS[1];
> W := L/Q;
> W;
Lie Algebra of dimension 7 with base ring GF(2^3)
> Z := Centre(W);
> z := Z.1;
> exists(u1,v1){ <u,v> : u,v in W | u*v ne 0 and u*v eq z };
true
> W1 := Centraliser(W,sub<W|u1,v1>);
true
> exists(u2,v2){ <u,v> : u,v in W1 | u*v ne 0 and u*v eq z };
true
> W2:= Centraliser(W1,sub<W1|u2,v2>);
> exists(u3,v3){ <u,v> : u,v in W2 | u*v ne 0 and u*v eq z };
> H := HeisenbergAlgebra(J);
> f := hom< H -> W | u1,u2,u3,v3,v2,v1,z >;
> forall{ <u,v> : u,v in Basis(H) | f(u*v) eq f(u)*f(v) };
true
> Kernel(f);
Lie Algebra of dimension 0 with base ring GF(2^3)
> Image(f) eq W;
true
V2.28, 13 July 2023