Example GrpPC_VerbosePrinting (H69E38)

We demonstrate the verbose printing by constructing a random genus 2 group of order 3^{20 + 2}.

> G := RandomGenus2Group(3, [4, 6, 10]);
> #G eq 3^(4 + 6 + 10 + 2);
true
> Genus(G);
2

With the verbose printing, we can see steps of the algorithm.

> SetVerbose("TameGenus", 1);
> A := TGAutomorphismGroup(G);
Extracting the p-central tensor and computing pseudo-isometries.
Checking the radicals.
        dim(Rad_V) = 0
        dim(Rad_W) = 0
Writing tensor over its centroid.
Tensor has genus 2.
Computing the adjoint algebra.
        dim(Adj) = 40
Decomposing tensor into flat and sloped subtensors.
        Block dims = [ 4, 6, 10 ]
Number of sloped blocks to lift: 3.
Field is small enough, applying Pfaffian method.
Number of flat blocks to lift: 0.
Constructing the isometry group.
   G
   |   Sp ( 2 , 3 ^ 2 )
   *
   |   Sp ( 2 , 3 ^ 3 )
   *
   |   Sp ( 2 , 3 ^ 5 )
   *
   |   3 ^ 0    (unipotent radical)
   1
Constructing automorphism group from pseudo-isometries.

    Exponentp: BoolElt                  Default: true

Example GrpPC_RandomGenusGroups (H69E39)

We construct a random group using the TGRandomGroup constructor. Specifically, we create a group G with exponent 5 such that the commutator tensor [, ] has centroid containing K=GF(5⁷) with genus at most 2 and where (dim)_K (G/Φ(G)) = 8. First, we create the group.

> G := TGRandomGroup(5^7, 8, 2);
> #G eq 5^(7*(8 + 2));
true

We check that the genus of our group G is at most 2.

> Genus(G);
2

We verify that the commutator tensor has a centroid containing the field of order 5⁷.

> t := pCentralTensor(G, 1, 1);
> t;
Tensor of valence 3, U2 x U1 >-> U0
U2 : Full Vector space of degree 56 over GF(5)
U1 : Full Vector space of degree 56 over GF(5)
U0 : Full Vector space of degree 28 over GF(5)
> C := Centroid(t);
> Dimension(C);
7
> IsSimple(C);
true

    Exponentp: BoolElt                  Default: true

Example GrpPC_PrescribedBlocks (H69E40)

Unlike the TGRandomGroup constructor, if we want to construct a genus 2 group with prescribed block dimensions, we can do this with RandomGenus2Group. If we want an elementary abelian direct factor, we can append a sequence of 1s whose sum is the rank of such a factor. We construct a genus 2 group G with an indecomposable blocks of dimensions 10, 7, 4, 4, and 1. Therefore, G isomorphic to H x Z/(p), where H is directly indecomposable and of order 7^{25 + 2}.

> G := RandomGenus2Group(7, [10, 7, 4, 4, 1]);
> #G eq 7^(10 + 7 + 4 + 4 + 1 + 2);
true

We can see these blocks with the genus 2 signature of the group. See TGSignature for a description of the output.

> S := TGSignature(G);
> S;
[* <7, 25, 2>, <1, 0>,
    [ 7 ],
    [*
        [ 1, 0, 1 ],
        [ 1, 4, 5 ],
        [ 1, 3, 3, 2, 6, 3 ]
    *]
*]

    Exponentp: BoolElt                  Default: true

Example GrpPC_Heisenbergs (H69E41)

The classic Heisenberg group over a field is an example of a genus 1 group, and one can generalize this construction in a number of ways. We will create a matrix group, over GF(81), as a polycyclic group.

> G := RandomGenus1Group(81, 2, 0);
> #G eq 81^(2*2 + 1);
true

We verify that G has genus 1 and that the derived subgroup is isomorphic to (Z/(3))⁴.

> D := DerivedSubgroup(G);
> IsElementaryAbelian(D);
true
> #D eq 3^4;
true

Although the underlying field GF(81) is hidden within the relations of the polycyclic presentation, we can still construct it and compute the genus over this larger field.

> Genus(G);
1

Example GrpPC_Pfaffians (H69E42)

We construct the genus 2 group G whose (univariate) Pfaffian is equivalent to f(x) = x³(x - 1)²(x - 2) in GF(9)[x]. Therefore, we expect |G|=9^{2.6 + 2}.

> P<x> := PolynomialRing(GF(9));
> f := x^3*(x-1)^2*(x-2);
> G := Genus2Group(f);
> #G eq 9^(2*6 + 2);
true

The genus 2 signature reveals the block structure. All six perp-indecomposable subspaces are 2-dimensional.

> S := TGSignature(G);
> S;
[* <9, 12, 2>, <0, 0>,
    [],
    [*
        [ 1, 1 ],
        [ 1, 0, 0 ],
        [ 0, 0, 0, 1 ]
    *]
*]

The output shows that the homogenization of f is equivalent to the polynomial g(x, y) = x²y³(x + y) in GF(q)[x, y].

Example GrpPC_DecomposableGroups (H69E43)

We create a decomposable genus 2 group from the TameGenus constructors. For example, the group G with a Pfaffian equivalent to xy is decomposable.

> P<x, y> := PolynomialRing(GF(7), 2);
> f := x*y;
> G := Genus2Group(f);
> G;
GrpPC : G of order 117649 = 7^6
PC-Relations:
G.3^G.1 = G.3 * G.5,
G.4^G.2 = G.4 * G.6
> IsIndecomposable(G);
false

This example also shows that TGRandomGroup may return a group that is directly decomposable.

Example GrpPC_DirectNotCentral (H69E44)

We create a directly indecomposable group G that is a central product of two genus 2 groups.

> G := RandomGenus2Group(5, [3, 4]);
> #G eq 5^(3 + 4 + 2);
true
> IsIndecomposable(G);
true

We observe the central factors from the genus 2 signature of G. We see that G is a central product of genus 2 groups of order 5⁵ and 5⁶.

> TGSignature(G);
[* <5, 7, 2>, <0, 0>,
    [ 3 ],
    [*
        [ 1, 0, 2 ]
    *]
*]

Example GrpPC_Genus (H69E45)

We determine the genus of some groups in the Small Group library. Let G be the group of order 3⁶ with ID number 440. Its derived subgroup is isomorphic to (Z/(3))², and G is genus 2.

> G := SmallGroup(3^6, 440);
> #DerivedSubgroup(G) eq 3^2;
true
> IsElementaryAbelian(DerivedSubgroup(G));
true
> Genus(G);
2

Let H be the group of order 3⁶ with ID number 469. Its derived subgroup is isomorphic to (Z/(3))² also, but H is genus 1.

> H := SmallGroup(3^6, 469);
> #DerivedSubgroup(H) eq 3^2;
true
> IsElementaryAbelian(DerivedSubgroup(H));
true
> Genus(H);
1

We can see this difference in genus in multiple ways. If we extract the commutator tensor from both groups, one is bilinear over a quadratic field extension where the other tensor is not. The algebra that records this is the centroid of a tensor, see Centroid.

> s := pCentralTensor(G, 1, 1);
> t := pCentralTensor(H, 1, 1);
> C_G := Centroid(s);
> C_H := Centroid(t);
> C_G;
Matrix Algebra of degree 6 with 2 generators over GF(3)
> C_H;
Matrix Algebra of degree 6 with 2 generators over GF(3)

The centroid associated to the tensor s is 2-dimensional but with a nontrivial Jacobson radical. The centroid associated to the tensor t is 2-dimensional and a simple GF(3)-algebra.

> Dimension(C_G);
2
> Dimension(C_H);
2
> WedderburnDecomposition(C_G);
Matrix Algebra of degree 6 with 1 generator over GF(3)
Matrix Algebra of degree 6 with 1 generator over GF(3)
> IsSimple(C_H);
true

Example GrpPC_NonExample (H69E46)

We create a group that is not covered by the TameGenus package. The small groups of order 3⁶ with IDs 440 and 469 both have tame genus: 2 and 1 respectively. The direct product of the two groups has genus 2, but because the group is not directly indecomposable, the current implementation of TameGenus cannot handle it.

> H1 := SmallGroup(3^6, 440);
> H2 := SmallGroup(3^6, 469);
> G := DirectProduct(H1, H2);
> G;
GrpPC : G of order 531441 = 3^12
PC-Relations:
    G.2^G.1 = G.2 * G.5,
    G.3^G.1 = G.3 * G.6,
    G.3^G.2 = G.3 * G.5,
    G.4^G.1 = G.4 * G.5,
    G.8^G.7 = G.8 * G.11,
    G.9^G.7 = G.9 * G.12,
    G.9^G.8 = G.9 * G.11^2 * G.12,
    G.10^G.7 = G.10 * G.11 * G.12,
    G.10^G.8 = G.10 * G.11
> IsTameGenusGroup(G);
false

Example GrpPC_AllTheSmallGroups (H69E47)

We use the IsTameGenusGroup to filter large databases down to the ones covered by TameGenus. We do that with the Small Group library for groups of order 3⁶, and we find there are seven such groups. Recall, that these groups must have prime exponent.

> G2_SG := [*G : G in SmallGroups(3^6) | IsTameGenusGroup(G)*];
> #G2_SG;
7

We further filter these groups based on their genus, and we find that there are six groups of positive genus and one abelian group.

> G1 := [*G : G in G2_SG | Genus(G) eq 1*];
> G2 := [*G : G in G2_SG | Genus(G) eq 2*];
> #G1;
3
> #G2;
3

We determine the tame genus signatures to show that all these groups yield different signatures. We first consider the genus 1 groups.

> for G in G1 do
>     TGSignature(G);
> end for;
[* <9, 2, 1>, <0, 0>, [* *], [* *] *]
[* <3, 2, 1>, <3, 0>, [* *], [* *] *]
[* <3, 4, 1>, <1, 0>, [* *], [* *] *]

The genus 2 groups have the following signatures.

> for G in G2 do
>     TGSignature(G);
> end for;
[* <3, 3, 2>, <1, 0>,
    [ 3 ],
    [* *]
*]
[* <3, 4, 2>, <0, 0>,
    [],
    [*
        [ 0, 0, 1 ]
    *]
*]
[* <3, 4, 2>, <0, 0>,
    [],
    [*
        [ 1, 0 ],
        [ 0, 1 ]
    *]
*]

    Cent: BoolElt                       Default: true

    Constructive: BoolElt               Default: true

    Method: RngIntElt                   Default: 0

Example GrpPC_IsomorphismTesting (H69E48)

We create an isomorphic pair of groups in two different ways, and then we construct an isomorphism between the two. This example can be seen as verifying Theorem 1.1 of [LM18]. We construct groups G and H from two random irreducible cubic polynomials in GF(67)[x].

> f := RandomIrreduciblePolynomial(GF(67), 3);
> g := RandomIrreduciblePolynomial(GF(67), 3);
> f, g;
$.1^3 + 36*$.1^2 + 26*$.1 + 33
$.1^3 + 57*$.1^2 + 24*$.1 + 65
> G := Genus2Group(f);
> H := Genus2Group(g);

In this case, the default method will run the adjoint-tensor method. We can see this if we turn on verbose printing.

> SetVerbose("TameGenus", 1);
> isomorphic, phi := TGIsIsomorphic(G, H);
Extracting p-central tensors and deciding pseudo-isometry.
Checking the radicals.
        dim(Rad_V) = 0
        dim(Rad_W) = 0
Checking the radicals.
        dim(Rad_V) = 0
        dim(Rad_W) = 0
Writing tensor over its centroid.
Writing tensor over its centroid.
Computing the adjoint algebra.
        dim(Adj_s) = 12
        dim(Adj_t) = 12
Computing the adjoint algebra.
Genus 2 case.
Decomposing tensors into flat and sloped subtensors.
        Block dims = [ 6 ]
PGammaL is larger than symmetric group, applying adjoint-tensor method.

We see that the two groups are isomorphic, and φ is such an isomorphism.

> isomorphic;
true
> phi;
Homomorphism of GrpPC : G into GrpPC : H induced by
    G.1 |--> H.1 * H.2^41 * H.3^30 * H.4^58 * H.5^43 * H.6^30
    G.2 |--> H.1^53 * H.2^4 * H.3^34 * H.4^54 * H.5^6 * H.6^25
    G.3 |--> H.1^5 * H.2^7 * H.3^49 * H.4^52 * H.5^21 * H.6^7
    G.4 |--> H.1^30 * H.2^4 * H.3^17 * H.4^53 * H.5^40 * H.6^9
    G.5 |--> H.1^14 * H.2^21 * H.3^30 * H.4^24 * H.5^38 * H.6^34
    G.6 |--> H.1^47 * H.2^46 * H.3^66 * H.4^65 * H.5^30 * H.6^30
    G.7 |--> H.7^10 * H.8^18
    G.8 |--> H.7^54 * H.8^12

To run the Pfaffian test, set the Method to 2. This method is noticeably slower for these groups and should not be used for very large primes.

> isomorphic, phi2 := TGIsIsomorphic(G, H : Method := 2);
Extracting p-central tensors and deciding pseudo-isometry.
Checking the radicals.
        dim(Rad_V) = 0
        dim(Rad_W) = 0
Checking the radicals.
        dim(Rad_V) = 0
        dim(Rad_W) = 0
Writing tensor over its centroid.
Writing tensor over its centroid.
Computing the adjoint algebra.
        dim(Adj_s) = 12
        dim(Adj_t) = 12
Computing the adjoint algebra.
Genus 2 case.
Decomposing tensors into flat and sloped subtensors.
        Block dims = [ 6 ]
Method set to Pfaffian.
> phi2;
Homomorphism of GrpPC : G into GrpPC : H induced by
    G.1 |--> H.1^47 * H.2^54 * H.3^54
    G.2 |--> H.1^63 * H.2^33 * H.3^15
    G.3 |--> H.1^26 * H.2^3 * H.3^60
    G.4 |--> H.4^44 * H.5^61 * H.6^16
    G.5 |--> H.4^66 * H.5^26 * H.6^36
    G.6 |--> H.4^57 * H.5^6 * H.6^30
    G.7 |--> H.7^62 * H.8^42
    G.8 |--> H.7^18 * H.8^58

    Cent: BoolElt                       Default: true

    Constructive: BoolElt               Default: true

    Method: RngIntElt                   Default: 0

Example GrpPC_PseudoIsometries (H69E49)

A pair of alternating matrices determines a tensor of tame genus. We construct a pair of pseudo-isometric tensors by applying a change of bases map. This is essentially how Experiment A from [BMW17] was conducted. Generating random 50 x 50 matrices over GF(3), we construct two tensors s, t : GF(3)⁵⁰ x GF(3)⁵⁰ ↣ GF(3)².

> M := RandomMatrix(GF(3), 50, 50);
> N := RandomMatrix(GF(3), 50, 50);
> Forms1 := [M - Transpose(M), N - Transpose(N)];
> s := Tensor(Forms1, 2, 1);
> s;
Tensor of valence 3, U2 x U1 >-> U0
U2 : Full Vector space of degree 50 over GF(3)
U1 : Full Vector space of degree 50 over GF(3)
U0 : Full Vector space of degree 2 over GF(3)
> IsAlternating(s);
true

We construct a random invertible co-homotopism varphi = (varphi₁, varphi₀) such that varphi₁∈GL(50, 3) and varphi₀∈GL(2, 3). We define a new and pseudo-isometric tensor t=s^varphi in this way.

> X := Random(GL(50, 3));
> Y := Random(GL(2, 3));
> Maps := [*X, X, Y*];
> H := Homotopism(Maps, CohomotopismCategory(3));
> t := s @ H;
> t;
Tensor of valence 3, U2 x U1 >-> U0
U2 : Full Vector space of degree 50 over GF(3)
U1 : Full Vector space of degree 50 over GF(3)
U0 : Full Vector space of degree 2 over GF(3)
> s eq t;
false

We verify that both s and t are pseudo-isometric, and since we do not need to write these tensors over their centroid, we avoid that step by setting Cent to false.

> pisometric, Phi := TGIsPseudoIsometric(s, t : Cent :=false);
> pisometric;
true
> Phi.0;
[0 1]
[2 2]

    Cent: BoolElt                       Default: true

    Method: RngIntElt                   Default: 0

    Mat: BoolElt                        Default: false

Example GrpPC_FlatIndecomposable (H69E50)

We build a flat indecomposable genus 2, p-group G and construct its automorphism group. We know that Aut(G) maps surjectivity onto GL(2, p), so we verify that |Aut(G)| is divisible by |GL(2, p)| = (p² - 1)(p² - p). This corresponds to the quotient of the pseudo-isometry group by the isometry group.

> p := 541;
> G := RandomGenus2Group(p, [29]);
> #G eq p^(29 + 2);
true
> A := TGAutomorphismGroup(G);
> IsDivisibleBy(#A, #GL(2, p));
true

The isometry group of the corresponding commutator tensor has an elementary abelian unipotent radical of rank 28, and so is isomorphic to an extension of GL(1, p) by (Z/(p))²⁸, as seen in [BW12]. Therefore, we verify that we have constructed all automorphisms as

|Aut(G)| = (p - 1)p²⁸ .(p² - 1)(p² - p) .p^29.2.

> #A eq (p - 1)*p^28 * (p^2 - 1)*(p^2 - p) * p^(29*2);
true

    Cent: BoolElt                       Default: true

    Method: RngIntElt                   Default: 0

Example GrpPC_Extensions (H69E51)

For K-vector spaces V and W, we create a genus 2 alternating tensor t: V x V ↣ W such that t is bilinear over an extension field E/K and (dim)_E(W)=2. One way to do this is with the constructors RandomGenus2Group and pCentralTensor.

> G := RandomGenus2Group(3^2, [6]);
> t := pCentralTensor(G, 1, 1);
> t;
Tensor of valence 3, U2 x U1 >-> U0
U2 : Full Vector space of degree 12 over GF(3)
U1 : Full Vector space of degree 12 over GF(3)
U0 : Full Vector space of degree 4 over GF(3)
> Genus(t);
2

The Pfaffian of t is an irreducible cubic over GF(9), so computing its pseudo-isometry group may contain elements of (Gal)(GF(9)).

> PI := TGPseudoIsometryGroup(t);
> Random(PI);
[0 1 0 0 0 2 1 1 0 2 1 0 0 0 0 0]
[2 0 0 0 1 0 0 2 1 0 1 2 0 0 0 0]
[1 1 0 0 0 1 1 1 0 0 2 1 0 0 0 0]
[0 2 0 0 2 0 0 2 0 0 1 1 0 0 0 0]
[1 2 2 0 0 2 2 2 1 0 0 0 0 0 0 0]
[2 2 2 1 1 0 0 1 1 2 0 0 0 0 0 0]
[2 2 2 0 1 0 1 0 2 2 1 2 0 0 0 0]
[0 1 2 1 1 2 1 2 0 1 2 2 0 0 0 0]
[2 0 1 0 2 2 2 1 1 1 0 0 0 0 0 0]
[2 1 1 2 0 1 1 1 0 2 0 0 0 0 0 0]
[0 2 0 1 2 2 1 1 0 1 1 0 0 0 0 0]
[1 0 2 0 0 1 0 2 2 0 1 2 0 0 0 0]
[0 0 0 0 0 0 0 0 0 0 0 0 0 1 1 0]
[0 0 0 0 0 0 0 0 0 0 0 0 2 0 1 2]
[0 0 0 0 0 0 0 0 0 0 0 0 1 1 0 0]
[0 0 0 0 0 0 0 0 0 0 0 0 0 2 0 0]
> Factorization(#PI);
[ <2, 8>, <3, 7>, <5, 1>, <7, 1>, <13, 1>, <73, 1> ]

Indeed, the pseudo-isometry group may not be linear over the centroid but semi-linear. To see the discrepancy, we rewrite t over its centroid and determine its pseudo-isometry group as a subgroup of GL_E(V) x GL_E(W). Note that this group is smaller by a factor of 2. We see that the pseudo-isometry group of t is strictly semi-linear over GF(9), as there exists a Galois involution.

> s := TensorOverCentroid(t);
> s;
Tensor of valence 3, U2 x U1 >-> U0
U2 : Full Vector space of degree 6 over GF(3^2)
U1 : Full Vector space of degree 6 over GF(3^2)
U0 : Full Vector space of degree 2 over GF(3^2)
> PI_C := TGPseudoIsometryGroup(s);
> Random(PI_C);
[    1 $.1^7     1 $.1^2 $.1^2 $.1^5     0     0]
[  $.1     2 $.1^7 $.1^3 $.1^6 $.1^5     0     0]
[$.1^7 $.1^2 $.1^7     1 $.1^6 $.1^2     0     0]
[$.1^7 $.1^7 $.1^7 $.1^3 $.1^7     1     0     0]
[    2 $.1^6 $.1^3 $.1^2 $.1^3     0     0     0]
[$.1^7   $.1 $.1^7 $.1^6 $.1^6 $.1^7     0     0]
[    0     0     0     0     0     0     2 $.1^7]
[    0     0     0     0     0     0 $.1^3 $.1^5]
> Factorization(#PI_C);
[ <2, 7>, <3, 7>, <5, 1>, <7, 1>, <13, 1>, <73, 1> ]

Example GrpPC_ManyBlocks (H69E52)

We construct a genus 2 group G isomorphic to A x H, where A is abelian and H is directly indecomposable but is the central product of many smaller genus 2 groups.

> blocks := [1, 1, 1, 2, 2, 3, 3, 5, 6];
> G := RandomGenus2Group(9, blocks);
> #G eq 9^(&+blocks + 2);
true

Because G was created with the field GF(9) and since there are three 1-dimensional blocks, we expect |A| = 9³ = 3⁶.

> TGSignature(G);
[* <9, 21, 2>, <6, 0>,
    [ 3, 3, 5 ],
    [*
        [ 0, 1 ],
        [ 1, 1 ],
        [ 1, 2, 2, 2 ]
    *]
*]

The first entry of this list tells us that the group H has order 9^{21 + 2} and that the commutator tensor of H is GF(9)-bilinear. The second entry reports that A isomorphic to (Z/(3))⁶. The third and fourth entries show that H is a central product of six indecomposable groups: three flats of orders 9^{3 + 2}, 9^{3 + 2}, and 9^{5 + 2}, and three sloped with Pfaffians in GF(9)[x, y] equivalent to

y, x + y, x³ + 2x²y + 2xy² + 2y³.

Example GrpPC_MoreSmallGroups (H69E53)

We run through all the small groups of order 3⁷ and determine their tame genus signatures. There are 9310 such groups, and 10 of them are covered by TameGenus.

> TG_SG := SmallGroupProcess(3^7, IsTameGenusGroup);
>
> repeat
>     G := Current(TG_SG);
>     _, ID := CurrentLabel(TG_SG);
>     print "Small group ID:", ID;
>     TGSignature(G);
>     Advance(~TG_SG);
> until IsEmpty(TG_SG);

The loop yields the following output.

Small group ID: 9106
[* <3, 3, 2>, <2, 0>,
    [ 3 ],
    [* *]
*]
Small group ID: 9107
[* <3, 4, 2>, <1, 0>,
    [],
    [*
        [ 1, 0 ],
        [ 0, 1 ]
    *]
*]
Small group ID: 9108
[* <3, 4, 2>, <1, 0>,
    [],
    [*
        [ 0, 0, 1 ]
    *]
*]
Small group ID: 9109
[* <9, 2, 1>, <1, 0>, [* *], [* *] *]
Small group ID: 9110
[* <3, 5, 2>, <0, 0>,
    [ 3 ],
    [*
        [ 0, 1 ]
    *]
*]
Small group ID: 9111
[* <3, 5, 2>, <0, 0>,
    [ 5 ],
    [* *]
*]
Small group ID: 9302
[* <3, 2, 1>, <4, 0>, [* *], [* *] *]
Small group ID: 9305
[* <3, 4, 1>, <2, 0>, [* *], [* *] *]
Small group ID: 9308
[* <3, 6, 1>, <0, 0>, [* *], [* *] *]
Small group ID: 9310
[* <3, 7, 0>, <7, 0>, [* *], [* *] *]