Documentation

Elliptic Curves

Creation

Modular abelian varieties of dimension 1 are elliptic curves. Given a modular abelian variety A over Q of dimension 1, Magma can compute an elliptic curve that is isogenous over Q to A. Given an elliptic curve E over Q, a modular abelian variety over Q that is isogenous to E can be constructed.

It would be very desirable to make these commands more precise, and to extend them to work over other fields. For example, modular abelian varieties should (conjecturally) be associated to Q-curves and their restriction of scalars.

EllipticCurve(A) : ModAbVar -> CrvEll

An elliptic curve isogenous to the modular abelian variety A over the rational field, if there is an elliptic curve associated to A. For A of weight greater than 2 use the EllipticInvariants command.

ModularAbelianVariety(E) : CrvEll -> ModAbVar

    Sign: RngIntElt                     Default: 0

A modular abelian variety isogenous to the elliptic curve E. Note that elliptic curves with small coefficients can have quite large conductor, hence computing the massive modular abelian variety that has E as quotient, which is one thing this function does, could take some time.

Example `ModAbVar_Ellcrv-Creation (H145E122)`

We apply the above two commands to the elliptic curve J₀(49).

> A := JZero(49);
> E := EllipticCurve(A); E;
Elliptic Curve defined by y^2 + x*y = x^3 - x^2 - 2*x - 1 over
Rational Field
> B := ModularAbelianVariety(E); B;
Modular abelian variety 'Cremona 49A' of dimension 1 and level
7^2 over Q

To see how A and B compare, we first test equality and see they are not equal (since they were constructed differently). However, they are isomorphic.

> B eq A;
false
> IsIsomorphic(A,B);
true Homomorphism from JZero(49) to 'Cremona 49A' given on integral
homology by:
[1 0]
[0 1]
> phi := NaturalMap(A,B);
> Degree(phi);
1
> phi;
Homomorphism N(1) from JZero(49) to 'Cremona 49A' given on integral
homology by:
[1 0]
[0 1]

Thus B is embedded in A via the identity map.

Invariants

Let A be an abelian variety over Q of dimension 1. The following two functions use standard iterative algorithms (see Cremona's book) to compute the invariants c₄, c₆, j, and generators of the period lattice of the optimal quotient of J₀(N) associated to A.

EllipticInvariants(A, n) : ModAbVar, RngIntElt -> FldReElt, FldReElt, FldReElt, CrvEll

Invariants c₄, c₆, j, and an elliptic curve, of the one dimensional modular abelian variety A, computed using n terms of q-expansion.

EllipticPeriods(A, n) : ModAbVar, RngIntElt -> FldReElt, FldReElt

Elliptic periods w₁ and w₂ of the J₀(N)-optimal elliptic curve associated to the modular abelian variety A, computed using n terms of the q-expansion. The periods have the property that w₁/w₂ has positive imaginary part.

Example `ModAbVar_Ellcrv-Invariants (H145E123)`

> A := ModularAbelianVariety("100A");
> c4,c6,j,E := EllipticInvariants(A,100);
> c4;
1600.0523183040458033068678491117208 +  0.E-25*i
> c6;
-44002.166592330033618811790218678607 +  0.E-24*i
> j;
3276.80112729920227590594817065393 +  0.E-25*i
> E;
Elliptic Curve defined by y^2 = x^3 +
(-43201.412594209236689285431925551172 +  0.E-24*i)*x +
(2376116.99598582181541583667180037300 +  0.E-22*i) over Complex
Field
> jInvariant(E);
3276.80112729920227590594817070563 +  0.E-25*i
> w1,w2 := EllipticPeriods(A,100);
> w1;
1.263088700712760693712816573302450091088 +  0.E-38*i
> w2;
 0.E-38 - 1.01702927066995984919787906165005620863321*i
> w1/w2;
 0.E-38 + 1.2419393788742296224466874060948650840497*i

V2.28, 13 July 2023

Contents