Documentation

Representations

This section describes basic functionality for Lie algebra representations: see Chapter REPRESENTATIONS OF LIE GROUPS AND ALGEBRAS for more functions for highest weight representations and decompositions.

StandardRepresentation(G) : GrpLie -> Map

The standard (projective) representation of the semisimple group of Lie type G over an extension its base ring. In other words, the smallest dimension highest-weight representation. For the classical groups, this is the natural representation. If this is a projective representation rather than a linear representation, a warning is given. This is constructed from the corresponding Lie algebra representation, using the algorithm in [CMT04].

AdjointRepresentation(G) : GrpLie -> Map, AlgLie

The adjoint (projective) representation of the group of Lie type G over an extension of its base ring, i.e. the representation given by the action of G on its Lie algebra. The Lie algebra itself is the second returned value. This is constructed from the corresponding Lie algebra representation, using the algorithm in [CMT04].

LieAlgebra(G) : GrpLie -> AlgLie, Map

The Lie algebra of the group of Lie type G, together with the adjoint representation. If this is a projective representation rather than a linear representation, a warning is given.

HighestWeightRepresentation(G, v) : GrpLie, . -> Map

The highest weight (projective) representation with highest weight v of the group of Lie type G over an extension of its base ring. If this is a projective representation rather than a linear representation, a warning is given. This is constructed from the corresponding Lie algebra representation, using the algorithm in [CMT04].

Example `GrpLie_StandardRepresentation (H110E24)`

> G := GroupOfLieType("A2", Rationals() : Isogeny := "SC");
> rho := StandardRepresentation(G);
> rho(elt< G | 1 >);
[ 0 -1  0]
[ 1  0  0]
[ 0  0  1]
> rho(elt<G | <2,1/2> >);
[  1   0   0]
[  0   1   0]
[  0 1/2   1]
> rho(elt< G | VectorSpace(Rationals(),2)![3,5] >);
[  3   0   0]
[  0 5/3   0]
[  0   0 1/5]
>
> G := GroupOfLieType("A2", Rationals());
> Invariants(CoisogenyGroup(G));
[ 3 ]
> rho := StandardRepresentation(G);
Warning: Projective representation
> BaseRing(Codomain(rho));
Algebraically closed field with no variables
> rho(elt< G | VectorSpace(Rationals(),2)![3,1] >);
[r1  0  0]
[ 0 r2  0]
[ 0  0 r2]
> rho(elt< G | VectorSpace(Rationals(),2)![3,1] >)^3;
[  9   0   0]
[  0 1/3   0]
[  0   0 1/3]

ContravariantForm(ρ) : Map[GrpLie,GrpMat] -> AlgMatElt

A contravariant form for the image of the matrix representation ρ of a group of Lie type.