To: GalRep                          Default: 

Example GalRep_galrep-minimize (H57E49)

We take an extension F of K=Q₃ with Galois group F₅=C₅:C₄ of order 20. It has five irreducible representations. Four of them are 1-dimensional, and so they actually factor through a smaller Galois group (C₁, C₂ or C₄). Minimize descends them to these Galois groups, although they are of course still the same as representations of the absolute Galois group.

> K:=pAdicField(3,20);
> R<x>:=PolynomialRing(K);
> list:=GaloisRepresentations(x^5-3);
> list;
[
1-dim trivial Galois representation 1 over Q3[20],
1-dim unramified Galois representation (1,1,-1,-1,1) with G=F5, I=C5
   over Q3[20],
1-dim unramified Galois representation (1,-1,-zeta(4)_4,zeta(4)_4,1)
   with G=F5, I=C5 over Q3[20],
1-dim unramified Galois representation (1,-1,zeta(4)_4,-zeta(4)_4,1)
   with G=F5, I=C5 over Q3[20],
4-dim Galois representation (4,0,0,0,-1) with G=F5, I=C5, conductor 3^4
   over Q3[20]
]
> [Minimize(A): A in list];
[
1-dim trivial Galois representation 1 over Q3[20],
1-dim unramified Galois representation (1,-1) with G=C2, I=C1 over Q3[20],
1-dim unramified Galois representation (1,-1,-zeta(4)_4,zeta(4)_4)
   with G=C4, I=C1 over Q3[20],
1-dim unramified Galois representation (1,-1,zeta(4)_4,-zeta(4)_4)
   with G=C4, I=C1 over Q3[20],
4-dim Galois representation (4,0,0,0,-1) with G=F5, I=C5, conductor 3^4
   over Q3[20]
]
> forall{A: A in list | A eq Minimize(A)};
true

Finally, we illustrate how the parameter To may be used to descend a Galois representation to a specific Galois group, in this case the Galois group Gal(F/K) isomorphic to C₄ of the degree 4 unramified extension of K.

> F:=ext<K|4>;                    // Take F = degree 4 unr. ext. of K, and
> B:=PermutationCharacter(F,K);   // any B with BaseField(B)=K, Field(B)=F
> list[2];
1-dim unramified Galois representation (1,1,-1,-1,1) with G=F5, I=C5 over Q3[20]
> Minimize(list[2]: To:=B);
1-dim unramified Galois representation (1,1,-1,-1) with G=C4, I=C1 over Q3[20]
> Minimize(list[2]);
1-dim unramified Galois representation (1,-1) with G=C2, I=C1 over Q3[20]

Example GalRep_galrep-basechange (H57E50)

We take a 2-dimensional irreducible representation of Gal(Q₂(ζ₃, root 3 of 2)) isomorphic to S₃ and check that its base change to Q₂(ζ₃) is reducible.

> K:=pAdicField(2,20);
> R<x>:=PolynomialRing(K);
> A:=GaloisRepresentations(x^3-2)[3]; A;
2-dim Galois representation (2,0,-1) with G=S3, I=C3, conductor 2^2 over Q2[20]
> L:=ext<K|2>;
> R:=Restriction(A,L); R;
2-dim Galois representation (2,-1,-1) with G=C3, I=C3, conductor 2^2
   over ext<Q2[20]|2>
> IsIrreducible(A),IsIrreducible(R);
true false

Example GalRep_galrep-induction (H57E51)

> K0:=pAdicField(2,20);     // K0=Q2
> K:=ext<K0|2>;             // K=Q2(zeta_3)
> R<x>:=PolynomialRing(K);
> A:=GaloisRepresentations(x^3-102)[3];
> A;                        // 1-dim character over K
1-dim Galois representation (1,-zeta(3)_3-1,zeta(3)_3) with G=C3, I=C3,
   conductor 2^1 over ext<Q2[20]|2>
> Induction(A,K0);          // Induced to K0
2-dim Galois representation (2,0,-1) with G=S3, I=C3, conductor 2^2 over Q2[20]