Eigenspace Decomposition and Eigenforms

HeckeEigenvalueBound(M, P) : ModFrmHil, RngOrdIdl -> RngIntElt
Returns a bound on the absolute value of the Hecke eigenvalue at the prime P which must hold for all newforms in the space M of Hilbert modular forms.
NewformDecomposition(M) : ModFrmHil -> List
Given a space M of Hilbert modular forms which was created as a NewSubspace, this decomposes M into subspaces that are irreducible modules under the Hecke action.
NewformsOfDegree1(M) : ModFrmHil -> List
This constructs the list of new eigenforms in M that have rational eigenvalues, i.e. corresponding to the 1-dimensional components in the NewformDecomposition. The space M is not required to be a new space. The algorithm avoids constructing the new subspace of M, and makes use of bounds on the eigenvalues.
Eigenform(M) : ModFrmHil -> ModFrmHilElt
This constructs an eigenform contained in the space M of Hilbert modular forms (which should be an irreducible module under the Hecke action, for instance a space obtained using NewformDecomposition).
Eigenforms(M) : ModFrmHil -> List
This is a list containing an eigenform from each space in NewformDecomposition(M).
HeckeEigenvalueField(M) : ModFrmHil -> Fld
Given a space M constructed using NewformDecomposition, this returns the number field over which the Eigenform of M is defined.
HeckeEigenvalue(f, P) : ModFrmHilElt, RngOrdIdl -> FldAlgElt
The computes the eigenvalue of the Hecke operator TP acting on the eigenform f (which should be a Hilbert modular form constructed using Eigenform).

Example ModFrmHil_eigenform-examples (H146E6)

We compute the newforms corresponding to elliptic curves over Q(Sqrt(2)) of conductor 11, and find there is only the one coming from Q. 
> R<x> := PolynomialRing(IntegerRing());
> F := NumberField(x^2-2);  OF := Integers(F);
> M := HilbertCuspForms(F, 11*OF);
> Dimension(M);
6
> time decomp := NewformDecomposition(NewSubspace(M)); decomp;
Time: 11.130
[*
    New cuspidal space of Hilbert modular forms of dimension 1 over
    Number Field with defining polynomial x^2 - 2 over the Rational Field
       Level = Ideal of norm 121 generated by ( [11, 0] )
       Weight = [ 2, 2 ],
    New cuspidal space of Hilbert modular forms of dimension 5 over
    Number Field with defining polynomial x^2 - 2 over the Rational Field
       Level = Ideal of norm 121 generated by ( [11, 0] )
       Weight = [ 2, 2 ]
*]
We look at the first few eigenvalues of the 1-dimension piece (at split primes). 
> f := Eigenform(decomp[1]);
> primes := [P : P in PrimesUpTo(40,F) | IsOdd(Norm(P)) and IsPrime(Norm(P))];
> for P in primes do
>   Norm(P),  HeckeEigenvalue(f,P);
> end for;
7 -2
7 -2
17 -2
17 -2
23 -1
23 -1
31 7
31 7
Happily, they agree with the eigenvalues of the elliptic cusp form of conductor 11 over Q: 
> fQ := Newforms(CuspForms(11))[1][1];
> for P in primes do
>   p := Norm(P);
>   p,  Coefficient(fQ, p);
> end for;
7 -2
7 -2
17 -2
17 -2
23 -1
23 -1
31 7
31 7
The 5-dimensional piece conjecturally corresponds to an abelian variety over F of dimension 5, which would be absolutely irreducible and have real multiplication by the following field. 
> K := HeckeEigenvalueField(decomp[2]);
> K;
Number Field with defining polynomial $.1^5 - 8*$.1^3 + 10*$.1 + 4 over F
> IsTotallyReal(K);
true
V2.28, 13 July 2023