Clifford Algebra Structure

Clifford algebras are associative structure constant algebras and therefore the intrinsics in chapters on structure constant algebras and associative algebras may be used with Clifford algebra arguments.

HomogeneousComponent(v,k) : AlgClffElt, RngIntElt -> AlgClffElt
The homogeneous component of degree k of the Clifford algebra element v.

Example AlgClff_HomComp (H95E5)

> F := GF(5);
> C,V,f := CliffordAlgebra(IdentityMatrix(F,4));
> v := (f(V.1)*f(V.2)+3*f(V.2))*(f(V.3)+f(V.4));
> AsPolynomial(HomogeneousComponent(v,2));
3*e1*e3 + 3*e2*e4
EvenSubalgebra(C : parameters) : AlgClff -> AlgAss, Map
The even subalgebra C_ + of the Clifford algebra C. This is the algebra of fixed points of the main involution. The second return value of this function is the canonical embedding of C_ + in C.

Example AlgClff_CliffGenQuatEx (H95E6)

A (generalised) quaternion algebra can also be realised as the even subalgebra of a Clifford algebra. 
> F<a,b> := RationalFunctionField(Rationals(),2);
> Q := DiagonalMatrix(F,[1,-a,-b]);
> C,V,f := CliffordAlgebra(Q);
> E, h := EvenSubalgebra(C);
> i := E.2;
> j := E.3;
> i^2;
(a 0 0 0)
> j^2;
(b 0 0 0)
> i*j eq -j*i;
true
Centre(C) : AlgClff -> AlgAss, Map
Center(C) : AlgClff -> AlgAss, Map
The centre of the Clifford algebra C. The second return value is the embedding in C.

The following examples illustrate the fact that over a finite field F a Clifford algebra C of a non-degenerate quadratic form Q is either a simple algebra or the direct sum of two simple algebras. Furthermore, the same is true of its even subalgebra E. Let V denote the quadratic space of Q.

Example AlgClff_EvenDimPlus (H95E7)

If the dimension of V is 2m and the Witt index of Q is m, then C is a central simple algebra. 
> F := GF(3);
> Q := StandardQuadraticForm(6,F);
> C,V,f := CliffordAlgebra(Q);
> WittIndex(V);
3
> IsSimple(C);
true
> #Centre(C);
3

The even subalgebra E of C is the direct sum of two simple ideals E(1 - z) and E(1 + z), where z2 = 1 and z anticommutes with every element of V. 

> E,h := EvenSubalgebra(C);
> IsSimple(E);
false
> #MinimalIdeals(E);
2
> Z := Centre(E); Z;
Associative Algebra of dimension 2 with base ring GF(3)
> #{ z : z in Z | IsUnit(z) };
4
> exists(z){ z : z in Z | z^2 eq One(E) and
>   forall{ v : v in V | f(v)*h(z) eq - h(z)*f(v) } };
true
> E1 := ideal< E | 1-z >;
> IsSimple(E1);
true
> E2 := ideal< E | 1+z >;
> IsSimple(E2);
true

Example AlgClff_EvenDimMinus (H95E8)

If dim V = 2m and the Witt index of Q is m - 1, the even subalgebra of C is a simple algebra whose centre is a quadratic extension of F. 
> F := GF(3);
> Q := StandardQuadraticForm(6,F : Minus);
> C,V,f := CliffordAlgebra(Q);
> WittIndex(V);
2
> IsSimple(C);
true
> #Centre(C);
3
> E := EvenSubalgebra(C);
> IsSimple(E);
true
> Z := Centre(E); Z;
Associative Algebra of dimension 2 with base ring GF(3)
> #{ z : z in Z | IsUnit(z) };
8

Example AlgClff_OddDim (H95E9)

If dim V = 2m + 1 and the Witt index of Q is m, the even subalgebra is central simple and C is the either simple or the direct sum of two simple algebras. 
> F := GF(3);
> Q := StandardQuadraticForm(5,F);
> C,V,f := CliffordAlgebra(Q);
> WittIndex(V);
2
> IsSimple(C);
false
> Z := Centre(C); Z;
Associative Algebra of dimension 2 with base ring GF(3)
> #{ z : z in Z | IsUnit(z) };
4
> E := EvenSubalgebra(C);
> IsSimple(E);
true
In this example the Clifford algebra is the direct sum of two simple ideals. But it is possible that the Clifford algebra of a scalar multiple of Q is a simple algebra over a quadratic extension of the base field. 
> C,V,f := CliffordAlgebra(2*Q);
> IsSimple(C);
true
> #Z,#{ z : z in Centre(C) | IsUnit(z) };
9 8
The non-zero elements of Z are invertible and hence Z is a field, namely GF(9).
V2.28, 13 July 2023