The real Cayley algebra

We construct the real Cayley algebra, which is a non-associative algebra of dimension 8, containing 7 quaternion algebras. If the basis elements are labelled and 1 corresponds to the identity, these quaternion algebras are spanned by , where . We first define a function, which, given three indices i,j,k constructs a sequence with the structure constants for the quaternion algebra spanned by 1,i,j,k in the quadruple notation.

> quat := func<i,j,k | [<1,1,1, 1>, <i,i,1, -1>, <j,j,1, -1>, <k,k,1, -1>,
>   <1,i,i, 1>, <i,1,i, 1>, <1,j,j, 1>, <j,1,j, 1>, <1,k,k, 1>, <k,1,k, 1>,
>   <i,j,k, 1>, <j,i,k, -1>, <j,k,i, 1>, <k,j,i, -1>, <k,i,j, 1>, <i,k,j, -1>]>;

We now define the sequence of non-zero structure constants for the Cayley algebra using the function quat. Some structure constants are defined more than once and we have to get rid of these when defining the algebra.

> con := &cat[quat((n+1) mod 7 +2, (n+2) mod 7 +2, (n+4) mod 7 +2):n in [0..6]];
> C := Algebra< Rationals(), 8 | Setseq(Set(con)) >;
> C;
Algebra of dimension 8 with base ring Rational Field
> IsAssociative(C);
false
> IsAssociative( sub< C | C.1, C.2, C.3, C.5 > );
true

The integral elements in this algebra are those where either all coefficients are integral or exactly 4 coefficients lie in in positions , such that are a basis of one of the 7 quaternion algebras or a complement of such a basis. These elements are called the integral Cayley numbers and form a -algebra. The units in this algebra are the elements with either one entry and the others 0 or with 4 entries and 4 entries 0, where the non-zero entries are in the positions as described above. This gives 240 units and they form (after rescaling with ) the roots in the root lattice of type .

> a := (C.1 - C.2 + C.3 - C.5) / 2;
> MinimalPolynomial(a);
$.1^2 - $.1 + 1
> MinimalPolynomial(a^-1);
$.1^2 - $.1 + 1
> MinimalPolynomial(C.2+C.3); 
$.1^2 + 2
> MinimalPolynomial((C.2+C.3)^-1);
$.1^2 + 1/2

Tensoring the integral Cayley algebra with a finite field gives a finite Cayley algebra. As the -algebra generated by the chosen basis for C has index in the full integral Cayley algebra, we can get the finite Cayley algebras by applying the ChangeRing function for finite fields of odd characteristic. The Cayley algebra over GF(q) has the simple group as its automorphism group. Since the identity has to be fixed, every automorphism is determined by its image on the remaining 7 basis elements. Each of these has minimal polynomial , hence one obtains a permutation representation of on the elements with this minimal polynomial. As -pairs have to be preserved, this number can be divided by 2.

> C3 := ChangeRing( C, GF(3) );
> f := MinimalPolynomial(C3.2);
> f;
$.1^2 + 1
> #C3;
6561
> time Im := [ c : c in C3 | MinimalPolynomial(c) eq f ];
Time: 3.099
> #Im;
702
> C5 := ChangeRing( C, GF(5) );
> f := MinimalPolynomial(C5.2);
> f;
$.1^2 + 1
> #C5;
390625
> time Im := [ c : c in C5 | MinimalPolynomial(c) eq f ];
Time: 238.620
> #Im;
15750

In the case of the Cayley algebra over GF(3) we obtain a permutation representation of degree 351, which is in fact the smallest possible degree (corresponding to the representation on the cosets of the largest maximal subgroup ). Over GF(5), the permutation representation is of degree 7875, corresponding to the maximal subgroup , the smallest possible degree being 3906.

Previous Group: A Jordan algebra