A Jordan algebra

We define a structure constant algebra which is a Jordan algebra.

> M := MatrixAlgebra( GF(3), 2 );
> B := Basis(M);
> C := &cat[Coordinates(M,(B[i]*B[j]+B[j]*B[i])/2) : j in [1..#B], i in [1..#B]];
> A := Algebra< GF(3), #B | C >;
> #A;
81
> IsAssociative(A);
false
> IsLie(A);        
false
> IsCommutative(A);
true

This is a good start, as one of the defining properties of Jordan algebras is that they are commutative. The other property is that the identity holds for all . We check this on a random pair.

> x := Random(A); y := Random(A);
> (x^2*y)*x - x^2*(y*x);
(0 0 0 0)

The algebra is small enough to check this identity on all elements.

> forall{<x, y>: x, y in A | (x^2*y)*x eq x^2*(y*x)};
true

So the algebra is in fact a Jordan algebra (which was clear by construction). We finally have a look at the structure constants.

> BasisProducts(A);
[
    [ (1 0 0 0), (0 2 0 0), (0 0 2 0), (0 0 0 0) ],
    [ (0 2 0 0), (0 0 0 0), (2 0 0 2), (0 2 0 0) ],
    [ (0 0 2 0), (2 0 0 2), (0 0 0 0), (0 0 2 0) ],
    [ (0 0 0 0), (0 2 0 0), (0 0 2 0), (0 0 0 1) ]
]

Next Group: The real Cayley algebra Previous Group: Finite Dimensional Algebras