Constructing an endo-trivial module

This example is due to Jon Carlson (Athens, GA, USA). The idea is to test a technique for constructing endo-trivial modules. An endo-trivial module is one with the property that is the direct sum of a trivial module and a projective (free, in this case) module.

First we construct an extraspecial group of order 27 and exponent 3.

> ps := PSL(3, 3);
> ps;
Permutation group ps acting on a set of cardinality 13
    (1, 10, 4)(6, 9, 7)(8, 12, 13)
    (1, 3, 2)(4, 9, 5)(7, 8, 12)(10, 13, 11)
> g := SylowSubgroup(ps, 3);
> g;
Permutation group g acting on a set of cardinality 13
Order = 27 = 3^3
    (3, 13, 9)(5, 8, 6)(7, 11, 12)
    (2, 5, 3)(4, 8, 9)(6, 13, 10)

Now we create the module in question. It is the kernel in an exact sequence where k is the trivial f3[g]-module and x is a permutation module whose point stabilizer is a noncentral cyclic subgroup.

> g.1 in Centre(g);
false
> h := sub<g | g.1>;
> h;
Permutation group h acting on a set of cardinality 13
    (2, 10, 4)(5, 8, 6)(7, 12, 11)
> F3 := GaloisField(3);
> x := PermutationModule(g, h, F3);
> hhh := GHom(x, TrivialModule(g, F3));
> hhh;
KMatrixSpace of 9 by 1 GHom matrices and dimension 1 over GF(3)

> delx := Kernel(hhh.1);
> delx;
GModule delx of dimension 8 over GF(3)
> xx := TensorProduct(delx, delx);
> xx;
GModule xx of dimension 64 over GF(3)

Now we want to decompose the tensor product of with itself. One of the summands should be an endo-trivial module. Note that the dimension of an endo-trivial module cannot be divisible by the prime 3, since the square of the dimension must be 1 plus a multiple of 27 (the order of the group g). The function IsDecomposable tests whether its argument is decomposable, and if this is the case then it also provides a decomposition as the second and third return values.

> a, m1, m2 := IsDecomposable(xx);
> a;
true
> m1, m2;
GModule m1 of dimension 9 over GF(3)
GModule m2 of dimension 55 over GF(3)

We want to check what the pieces are. We suspect that the module of dimension 9 is just a copy of our permutation module, and the check below confirms that. Then we proceed with the other piece.

> IsIsomorphic(m1, x);
true

> a,m3,m4 := IsDecomposable(m2);
> a, m3, m4;
true 
GModule m3 of dimension 27 over GF(3)
GModule m4 of dimension 28 over GF(3)

We suspect this time that the module of dimension 27 is a free module. We use the theorem that the free module is the only module with the property that it is generated by a single element and has dimension equal to the order of the group. So we try a couple of times to see if it can be generated by a single element.

> sub< m3 | Random(m3) >;
GModule of dimension 21 over GF(3)
> sub< m3 | Random(m3) >;
GModule m3 of dimension 27 over GF(3)

So m3 is a free module. We can proceed.

> IsDecomposable(m4);
false

Now we check to see if m4 is endo-trivial.

> et := TensorProduct(m4, Dual(m4));
> et;
GModule et of dimension 784 over GF(3)
> Quotrem(Dimension(et), #g);
29 1

So the dimension is 1 more than a multiple (29) of the order of g (27), as expected.

We know that the tensor product of m4 with its dual has a direct summand isomorphic to the trivial module. If it is endo-trivial then the tensor of it with its dual must be one copy of the trivial module plus copies of the free module. So the action of the group algebra must have exactly 29+1=30 fixed points. We check:

> Fix(et);
GModule of dimension 30 over GF(3)

Actually at this point we can be certain that m4 is an endo-trivial module. But just to be sure we factor out projective modules to see if we get down to the trivial module. We are using here the fact that the group ring is self-injective and hence any free submodule (module of dimension 27 generated by one element) is a direct summand.

> ww := et;
> Dim := Dimension; // shorthand
> repeat
>     sum := rep{s : i in [1..100] | Dim(s) eq 27 
>       where s is sub< ww | Random(ww) >};
>     qq := quo< ww | sum >;
>     print (Dim(et) - Dim(qq)) / #g, Dim(qq);
>     ww := qq;
> until Dim(qq) eq 1;
1 757
2 730
3 703
4 676
   [ etc ]
26 82
27 55
28 28
29 1

Finally we want to check that the module m4 is not one of the known endo-trivial modules. It is enough to see that it doesn't have the same restriction to all of the maximal elementary abelian subgroups. So we calculate all the maximal elementary abelian 3-subgroups. and then check the dimension of the fixed point set on each.

> cc := Centre(g);
> max1:= sub< g | g.1, cc >;
> max2:= sub< g | g.2, cc >;
> max3:= sub< g | g.1*g.2, cc >;
> max4:= sub< g | g.1*g.2^2, cc >;
> [ Fix(Restriction(m4, x)) : x in [max1, max2, max3, max4] ];
[
    GModule of dimension 6 over GF(3),
    GModule of dimension 4 over GF(3),
    GModule of dimension 4 over GF(3),
    GModule of dimension 4 over GF(3)
]

Notice that the single fixed-point space of dimension 6 corresponds to the restriction of m4 to the maximal subgroup containing the subgroup h with which we started.

Previous Group: Constituents of a module