Imprimitive degree 9 fields

In this example we illustrate how to construct some of the fields that are the subject of study in a certain paper, and show how to verify some of the results mentioned there. The paper is: F. Diaz y Diaz, M. Olivier, Imprimitive ninth-degree number fields with small discriminants, Math. Comp. 64 (1995), 305-321.

We begin with two special fields of signature (9, 0): first the maximal real subfield of the cyclotomic field .

> R<x> := PolynomialRing(IntegerRing());
> C<c> := CyclotomicField(19);
> f := MinimalPolynomial(c + c^-1);
> M<m> := NumberField(f);
> Signature(M);
9 0
> M;
Number Field with defining polynomial x^9 + x^8 - 8*x^7 - 7*x^6 + 21*x^5 + 
    15*x^4 - 20*x^3 - 10*x^2 + 5*x + 1 over the Rational Field
> Factorization(Discriminant(M));
[ <19, 8> ]

As expected, only the prime 19 ramifies in the field, and indeed it is totally ramified:

> Decomposition(MaximalOrder(M), 19); 
[
    <Ideal of Equation Order of M
    Two element generators:
        [19, 0, 0, 0, 0, 0, 0, 0, 0]
        [17, 1, 0, 0, 0, 0, 0, 0, 0], 9>
]

The next field is the composite field of where , and where . Note that we create a relative extension by a rational polynomial. The field contains two other non-isomorphic cubic subfields.

> k<a> := NumberField(x^3 + x^2 - 2*x - 1);
> Discriminant(k);
49

> M := ext< k | x^3 - 3*x - 1 >;
> N := AbsoluteField(M);
> N;
Number Field with defining polynomial x^9 + 3*x^8 - 12*x^7 - 38*x^6 + 21*x^5 + 
    93*x^4 - x^3 - 51*x^2 - 9*x + 1 over the Rational Field
> Factorization(Discriminant(N));
[ <3, 12>, <7, 6> ]
> S := Subfields(N);
> [ Discriminant(S[i][1]) : i in [1..#S]];
[ 62523502209, 3969, 3969, 81, 49 ]
> IsIsomorphic(S[2][1], S[3][1]);
false

The field L is one of 3 imprimitive degree 9 fields given in Diaz y Diaz and Olivier for which the class group is . We find its class group. We also find the cubic subfield; we show that it is isomorphic to k above and create the explicit isomorphism.

> L := NumberField(x^6 - 2*x^5 + 20*x^4 - 27*x^3 + 140*x^2 - 98*x + 343);
> MinkowskiBound(L);
205
> C, m := ClassGroup(L);
> C;
Abelian Group isomorphic to Z/3 + Z/3
Defined on 2 generators
Relations:
    3*C.1 = 0
    3*C.2 = 0
> Norm( m(C.1) ), Norm( m(C.2) );
7 27
> S := Subfields(L);
> S[2][1];
Number Field with defining polynomial x^3 - 22*x^2 + 159*x - 377
over the Rational Field
> H<h> := S[2][1]; g := S[2][2];
> fl, f := IsIsomorphic(k, H);
> fl;
true
> f(k.1);
h^2 - 14*h + 47
> MinimalPolynomial(g(f(k.1)));
$.1^3 + $.1^2 - 2*$.1 - 1

In Diaz y Diaz and Olivier's paper, 4 non-isomorphic fields are constructed that are all relative cubic extensions of discriminant -2045563163 of the cubic field k of discriminant 49 defined above.

We construct the 4 fields, using the given cubic polynomials, as relative and absolute extensions. We check the discriminants; note that the computation of the discriminant triggers the determination of the ring of integers.

We invoke the IsIsomorphic function on a pair of the degree 9 fields.

By just looking at the decomposition of the primes 11, 17 and 19 (as suggested by the authors) we see that the fields are non-isomorphic.

> R<x> := PolynomialRing(IntegerRing());
> k<a> := NumberField(x^3 + x^2 - 2*x - 1);
> b := a^2;
> Discriminant(k);
49

> S<s> := PolynomialRing(k);
> K1<z1> := ext< k | s^3 - (1-a)*s^2 + (4+a)*s - (5-a-2*b) >;
> L1 := AbsoluteField(K1);
> L1, Discriminant(L1);

Number Field with defining polynomial x^9 - 4*x^8 + 14*x^7 - 39*x^6 + 72*x^5 - 
    110*x^4 + 128*x^3 - 78*x^2 + 16*x - 1 over the Rational Field
-2045563163

> K2<z2> := ext< k | s^3 - (1-a)*s^2 + (-5+a+3*b)*s - (-8+a+4*b) >;
> L2 := AbsoluteField(K2);
> L2, Discriminant(L2);
Number Field with defining polynomial x^9 - 4*x^8 + 2*x^7 + 11*x^6 - 28*x^5 + 
    44*x^4 - 36*x^3 + 12*x^2 - 2*x - 13 over the Rational Field
-2045563163

> K3<z3> := ext< k | s^3 - (1-2*a-b)*s^2 + (-1+2*a+b)*s - (3-2*a-b) >;
> L3 := AbsoluteField(K3);
> L3, Discriminant(L3);
Number Field with defining polynomial x^9 - 7*x^7 - 13*x^6 + 42*x^4 + 82*x^3 + 
    84*x^2 + 49*x + 13 over the Rational Field
-2045563163

> K4<z4> := ext< k | s^3 - (1-2*a-b)*s^2 + (-1+2*a+b)*s - (2-2*b) >;
> L4 := AbsoluteField(K4);
> L4, Discriminant(L4);
Number Field with defining polynomial x^9 - 7*x^7 - 3*x^6 + 14*x^5 + 7*x^4 - 
    25*x^3 - 42*x^2 - 28*x - 8 over the Rational Field
-2045563163

> IsIsomorphic(L1, L2);
false
> [ [#Decomposition( MaximalOrder(L), p ) :
    p in [11, 13, 17] ] : L in [L1, L2, L3, L4] ];
[
    [ 3, 4, 1 ],
    [ 1, 6, 3 ],
    [ 1, 6, 1 ],
    [ 1, 4, 1 ]
]

Next Group: An octic field and its units Previous Group: Gaussian periods