Affine plane from a projective plane by derivation

We construct the collineation group in its action on the points of , for the case where q=16.

We begin by creating the projective plane PP from the finite field with 16 elements, along with the point-set and line-set of the plane. Then the collineation group G is formed.

> q := 16;
> F<w> := FiniteField(q);
> PP, Pts, Lns := ProjectivePlane(F);
> PP;
The projective plane PG(2, 16)
> #Pts, #Lns;
273 273

> G, gspt, gsln := CollineationGroup(PP);
> G;
Permutation group G acting on a set of cardinality 273
Order = 2^14 * 3^3 * 5^2 * 7 * 13 * 17

We next define a certain Hall oval, and print its points. We choose points P and Q on the oval and find the line PQ that contains P and Q. Then we choose a point X not on the line PQ: this is done by choosing another point on the oval.

> oval := { Pts | [1, x, w^4*x^14 + w^24*x^12 + w^12*x^10 + w^18*x^8 
>   + w^10*x^6 + w^10*x^4 + w^12*x^2] : x in F } 
>   join { Pts | [0,1,0], [0,0,1] };
> oval;
{ ( 1 : 0 : 0 ), ( 1 : w^4 : w^3 ), ( 1 : w : w^4 ), ( 0 : 1 : 0 ),
( 1 : w^5 : w^10 ), ( 1 : w^14 : w ), ( 0 : 0 : 1 ), ( 1 : w^10 : w^7 ), 
( 1 : w^13 : w^11 ), ( 1 : w^7 : w^8 ), ( 1 : w^11 : w^2 ), 
( 1 : w^12 : w^6 ), ( 1 : w^9 : w^5 ), ( 1 : w^6 : w^14 ), ( 1 : w^8 : w^12 ),
( 1 : w^2 : w^9 ), ( 1 : 1 : 1 ), ( 1 : w^3 : w^13 ) }

> P := Rep(oval);
> Q := Rep(Exclude(oval, P));
> P, Q;    
( 1 : 0 : 0 ) ( 0 : 1 : 0 )
> PQ := Lns![P, Q];          
> PQ;
< 0 : 0 : 1 >

> X := Rep(oval diff {P, Q});
> X;
( 1 : w^4 : w^3 )
> XP := Lns![X, P];
> XQ := Lns![X, Q];
> XP, XQ;
< 0 : 1 : w > < 1 : 0 : w^12 >

Now we construct: the group H1 of central collineations with axis PQ; the group H2 of elations with centre P and axis PQ; the group H3 of homologies with centre P and axis XQ; and the group H4 of central collineations with centre P and axis through Q.

> H1 := Stabilizer(G, gspt, Setseq(Set(PQ)));
> H2 := SylowSubgroup(Stabilizer(H1, gsln, XP), 2);
> H3 := Stabilizer(Stabilizer(G, gspt, P), gspt, Setseq(Set(XQ)));
> H4 := sub< G | H2, H3 >;

We construct the set afflines containing the lines of the new plane. They are: the translates of oval (excluding P and Q) under the central collineations: the lines of (excluding PQ) incident with P; and the lines of (excluding PQ) incident with Q. Then we can construct the affine plane itself.

> afflines := Orbit(H4, gspt, oval diff {P, Q}) join 
>   { Exclude(Set(l), Y) : l in Lns, Y in {P,Q} | l ne PQ and Y in l };
> #afflines;
272
> affpts := &join afflines;
> #affpts;           
256
> affpl := AffinePlane< SetToIndexedSet(affpts) | Setseq(afflines) >;
> affpl;
Affine plane of order 16

Finally, we check that the plane is desarguesian by calculating the p-rank, which equals the dimension of the corresponding linear code:

> C := LinearCode(affpl, PrimeField(F));
> Dimension(C);
81

Previous Group: Hermitian unital